Как запустить IE7 без инсталляции в системе
АрхивБраузерыВкусить все прелести пока еще бета-версии Internet Explorer 7, можно и без обязательной установки этого браузера в операционной системе Windows XP.
Жаждете хоть одним глазком взглянуть на Internet Explorer 7, да сдерживают статус бета-версии продукта и возможные коллизии при вынужденной деинсталляции программы? Не беда. Благодаря приему, изложенному на страницах блога Google Operating System, можно обойтись и без обязательной установки этого браузера в Windows XP. Приводим пошаговое изложение предложенного метода.
1. Первый шаг - загрузка браузера IE7 (11,9 Мб), не так давно обновившегося до второй редакции.
2. Вооружившись архиватором Winrar, распаковываем содержимое дистрибутива в директорию C:\Program Files\Internet Explorer 7. В случае отсутствия под рукой программы Winrar извлечь данные можно при помощи командной строки и инструкции IE7BETA2-WindowsXP-x86-enu.exe -e.
3. Создаем в новоиспеченной папке командный файл ie7.bat и, используя любой текстовый редактор, вставляем в него следующий код, автором которого числится Джон Гэллоуэй:
@ECHO OFF
TITLE IE7 Launcher 1.4
ECHO IE7 STANDALONE LAUNCHER 1.4
ECHO Updated for IE7 Beta 2 Preview
ECHO.
ECHO Do not close this window or it will not clean up after itself properly.
ECHO You can pass a URL into this batch file, like this:
ECHO ie7.bat www.microsoft.com
ECHO.
ECHO More info here: http://weblogs.asp.net/jgalloway/archive/2005/12/28/434132.aspx
ECHO.
ECHO When you close IE7, this will remove the registry key and shut itself down.
ECHO.
ECHO Setting up IE7 for standalone mode...
PUSHD %~dp0
ECHO Removing IE7 registry key and set the version vector to "7.0000".
> %TEMP%.\IE7Fix.reg ECHO REGEDIT4
>>%TEMP%.\IE7Fix.reg ECHO.
>>%TEMP%.\IE7Fix.reg ECHO [-HKEY_CLASSES_ROOT\CLSID\{C90250F3-4D7D-4991-9B69-A5C5BC1C2AE6}]
>>%TEMP%.\IE7Fix.reg ECHO [-HKEY_CLASSES_ROOT\Interface\{000214E5-0000-0000-C000-000000000046}]
>>%TEMP%.\IE7Fix.reg ECHO [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Version Vector]
>>%TEMP%.\IE7Fix.reg ECHO "IE"="7.0000"
>>%TEMP%.\IE7Fix.reg ECHO.
:: Merge the REG file to delete the IE7 standalone entry
REGEDIT /S %TEMP%.\IE7Fix.reg
REN SHLWAPI.DLL SHLWAPI.DLL.BAK
TYPE NUL > IEXPLORE.exe.local
ECHO Running IE7...
iexplore.exe "%1"
:: Merge the REG file to delete the IE7 standalone entry
REGEDIT /S %TEMP%.\IE7Fix.reg
:: Delete the temporary REG file
DEL %TEMP%.\IE7Fix.reg
ECHO Removing IE7 standalone files...
REN SHLWAPI.DLL.BAK SHLWAPI.DLL
DEL IEXPLORE.exe.local
:: Set the old version vector "6.0000".
> %TEMP%.\IE7Fix.reg ECHO REGEDIT4
>>%TEMP%.\IE7Fix.reg ECHO.
>>%TEMP%.\IE7Fix.reg ECHO [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Version Vector]
>>%TEMP%.\IE7Fix.reg ECHO "IE"="6.0000"
>>%TEMP%.\IE7Fix.reg ECHO.
REGEDIT /S %TEMP%.\IE7Fix.reg
DEL %TEMP%.\IE7Fix.reg
POPD
ECHO Complete, closing...
4. В этой же директории создаем еще один файл ie7.vbs со скриптом следующего содержания:
Set oShell = CreateObject("WScript.Shell")
oShell.Run "ie7.bat", 0, True
5. В папке C:\Program Files\Internet Explorer 7\Update находим файл xmllitesetup.exe, запускаем его и дожидаемся окончания работы инсталлятора.
6. Все, остается лишь кликнуть пару раз мышкой по файлу ie7.vbs для загрузки полноценной седьмой бета-версии Internet Explorer.
Обратите внимание, что можно одновременно работать как с IE7 Beta 2, так и с шестой версией браузера Microsoft, идущего в стандартной поставке операционной системы Windows XP.
